@echo off
title LexAcelerador - LIDE INVEST (instalacao)
set "DEST=%LOCALAPPDATA%\LexAcelerador"
echo.
echo  === LexAcelerador - LIDE INVEST ===
echo  Motor de transcricao local (whisper.cpp oficial v1.9.1).
echo  Tudo roda apenas neste computador.
echo.
echo  [1/3] Copiando o motor para %DEST% ...
xcopy /e /i /y "%~dp0motor" "%DEST%\motor" >nul
copy /y "%~dp0INICIAR-ACELERADOR.bat" "%DEST%\" >nul
copy /y "%~dp0BAIXAR-MAXIMA-PRECISAO.bat" "%DEST%\" >nul
echo  [2/3] Baixando o modelo Equilibrado (60 MB)...
curl -L --ssl-no-revoke --progress-bar -o "%DEST%\ggml-base-q5_1.bin" https://huggingface.co/ggerganov/whisper.cpp/resolve/main/ggml-base-q5_1.bin
echo  [3/3] Baixando o modelo Preciso (190 MB - pode demorar alguns minutos)...
curl -L --ssl-no-revoke --progress-bar -o "%DEST%\ggml-small-q5_1.bin" https://huggingface.co/ggerganov/whisper.cpp/resolve/main/ggml-small-q5_1.bin
echo.
set /p LIGAR="Ligar o acelerador agora? (S/N): "
if /i "%LIGAR%"=="S" start "" "%DEST%\INICIAR-ACELERADOR.bat"
echo.
set /p AUTO="Iniciar automaticamente com o Windows? (S/N): "
if /i "%AUTO%"=="S" copy /y "%DEST%\INICIAR-ACELERADOR.bat" "%APPDATA%\Microsoft\Windows\Start Menu\Programs\Startup\LexAcelerador.bat" >nul
echo.
set /p MAXPREC="Baixar tambem o modelo de Maxima Precisao agora (large-v3, 3,1 GB - opcional, pode demorar)? (S/N): "
if /i "%MAXPREC%"=="S" call "%DEST%\BAIXAR-MAXIMA-PRECISAO.bat"
echo.
echo  Pronto! Abra o LexActa em lideinvest.com.br - o selo verde acende sozinho.
echo  Para ligar manualmente depois: %DEST%\INICIAR-ACELERADOR.bat
echo  Para baixar o modelo de Maxima Precisao depois: %DEST%\BAIXAR-MAXIMA-PRECISAO.bat
echo.
pause
